// converter.txt
//Exactly like basicnpc, except that when fighing, it converts all 
//summoned creatures near it to be on its side. 
// Memory Cells:
//   Cell 0 - How creature moves.
//     0 - If 0, wander randomly. 
//     1 - Stands still until a target appears.
//     2 - Completely immobile, even if target appears.
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cells 4,5 - the coordinates for the northwest corner of the room this creature lives in
//   Cells 6,7 - the coordinates for the southeast corner
//   Cell 8 - if nonzero, gives this status to all the creatures it converts

begincreaturescript;

variables;

short i,target;
short x,y,a,b,c;

body;

beginstate INIT_STATE;
	if (get_memory_cell(0) == 2)
		set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
		else 
			set_target(ME,-1);
	}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
	}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
	}
		
	// Otherwise, just peacefully move around. Go back to start, if I'm too far
	// from where I started.
	if ((my_dist_from_start() >= 6) || ((my_dist_from_start() > 0) && (get_memory_cell(0) > 0))) {
		if (get_ran(1,1,100) < 40) 
			return_to_start(ME,1);
	}
	else if (get_memory_cell(0) == 0) {
		fidget(ME,25);
	}

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	a = get_attitude(ME);
	b = 0;
	y = get_memory_cell(5);
	while(y <= get_memory_cell(7)){
		x = get_memory_cell(4);
		while(x <= get_memory_cell(6)){
			c = char_on_spot(x,y);
			if(c > 5){
				if(get_summon_level(c) > 0 && get_attitude(c) != a){
					b = b + 1;
					set_attitude(c,a);
					put_sparkles_on_char(c,6,6);
					if(get_memory_cell(8) != 0)
						set_char_status(c,get_memory_cell(8),5,1,0);
				}
			}
			x = x + 1;
		}
		y = y + 1;
	}
	if(b > 0){
		if(b == 1)
			print_named_str(ME,"takes control of your summoned creature.");
		else
			print_named_str(ME,"takes control of your summoned creatures.");
		run_animation();
	}
	do_attack();
break;

beginstate TALKING_STATE;
	if (get_memory_cell(3) == 0) {
		print_str("Talking: It doesn't respond.");
		end();
	}
	begin_talk_mode(get_memory_cell(3));
break;